program pr09a; { Очередь в динамической памяти }
                { (c) 2005 by Gumanoid }
type
  link = ^node;
  node = record
    inf: integer;
    ref: link;
  end;

procedure push(var head, tail: link; x: integer);
var
  p: link;
begin
  new(p);      { Выделить ячейку памяти }
  p^.inf:=x;   { Записать в неё значение }
  p^.ref:=nil; { Последний элемент }
  if ((nil=head) and (nil=tail)) then { Если очередь пуста }
    begin
      head:=p;
      tail:=p;
    end
  else
    begin
      tail^.ref:=p; { Ссылка на добавленный элемент }
      tail:=p;      { Последний элемент }
    end;
end;

function pop(var head, tail: link; var x: integer): boolean;
var
  p: link;
begin
  if ((nil=head) and (nil=tail)) then
    pop:=false           { Если очередь пуста }
  else
    begin
      x:=head^.inf;      { Получить значение элемента }
      if head=tail then  { Если больше нет элементов }
        begin
          dispose(head); { Освободить память }
          head:=nil;
          tail:=nil;
        end
      else
        begin
          p:=head^.ref;  { Записать адрес 2-го элемента }
          dispose(head); { Освободить память }
          head:=p;
        end;
      pop:=true;
    end;
end;

procedure print_menu;
begin
  WriteLn;
  WriteLn('1. Добавить элемент');
  WriteLn('2. Извлечь элемент');
  WriteLn('3. Выйти');
  write('# ');
end;

var
  numb: byte;
  value: integer;
  head, tail: link;
  close_query: boolean;

begin
  close_query:=false;
  head:=nil;
  tail:=nil;
  while not close_query do
    begin
      print_menu;
      read(numb);
      case numb of
        1: begin
             write('Введите значение: ');
             read(value);
             push(head, tail, value);
           end;
        2: if pop(head, tail, value) then
             WriteLn(value)
           else
             WriteLn('Ошибка. Очередь пуста.');
        3: close_query:=true;
      end;
    end;
end.